Adding and editing (importing) registry entries

Adding items to the registry requires a *.REG file:

REGEDIT /S addsome.REG

Removing registry entries

To remove an entire "tree" from the registry using REGEDIT and a .REG file, just add a minus sign before the tree name:

REGEDIT4

[-HKEY_CURRENT_USER\DummyTree]

REGEDIT4

[HKEY_CURRENT_USER\DummyTree]
"ValueToBeRemoved"=-

Reading (exporting) from the registry

REGEDIT's /E switch can be used to export a registry key:

REGEDIT /E d:\path\filename.REG "HKEY_XXXX\Whatever Key"

All Win32 Versions

The following example deletes a file and a registry entry to force Intel LANDesk agent software to create a new unique ID.
Run it once on any PC containing Intel's LANDesk agent software that was installed using any "disk cloning" technique (like Norton Ghost, PowerQuest's Drive Image, or tape backups).

@ECHO OFF
:: No command line parameters required
IF NOT "%1"=="" GOTO Syntax

:: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: ::
:: Adjust the LANDesk server name and the drive and directory if necessary ::
:: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: :: ::
SET LANDeskServer=MyLDServer
C:
CD\LDClient

ECHO Removing old LANDesk agent ID

:: Delete old ID file (adjust drive if necessary)
IF EXIST C:\LDIScan.cfg ATTRIB -h -r -s C:\LDIScan.cfg
IF EXIST C:\LDIScan.cfg DEL C:\LDIScan.cfg

:: Delete old ID from the registry (Local Machine)
:: Create a temporary REG file
> %TEMP%.\UniqueID.reg ECHO REGEDIT4
>>%TEMP%.\UniqueID.reg ECHO.
>>%TEMP%.\UniqueID.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Intel\LANDesk\Common Api]
>>%TEMP%.\UniqueID.reg ECHO "UniqueID"=-
>>%TEMP%.\UniqueID.reg ECHO.

:: Check if previous ID was stored for Current User and if so, delete it
IF EXIST %TEMP%.\_Unique_.REG DEL %TEMP%.\_Unique_.REG
REGEDIT /E %TEMP%.\_Unique_.REG "HKEY_CURRENT_USER\SOFTWARE\Intel\LANDesk\LDWM\LDIScan32"
TYPE %TEMP%.\_Unique_.REG ¦ FIND /I "Last Device ID" >NUL 2>&1
IF ERRORLEVEL 1 GOTO Next
>>%TEMP%.\UniqueID.reg ECHO [HKEY_CURRENT_USER\SOFTWARE\Intel\LANDesk\LDWM\LDIScan32]
>>%TEMP%.\UniqueID.reg ECHO "Last Device ID"=-
>>%TEMP%.\UniqueID.reg ECHO.

:: Repeat for Default User
:Next
IF EXIST %TEMP%.\_Unique_.REG DEL %TEMP%.\_Unique_.REG
REGEDIT /E %TEMP%.\_Unique_.REG "HKEY_USERS\.Default\SOFTWARE\Intel\LANDesk\LDWM\LDIScan32"
TYPE %TEMP%.\_Unique_.REG ¦ FIND /I "Last Device ID" >NUL 2>&1
IF ERRORLEVEL 1 GOTO Merge
DEL %TEMP%.\_Unique_.REG
>>%TEMP%.\UniqueID.reg ECHO [HKEY_USERS\.Default\SOFTWARE\Intel\LANDesk\LDWM\LDIScan32]
>>%TEMP%.\UniqueID.reg ECHO "Last Device ID"=-
>>%TEMP%.\UniqueID.reg ECHO.

:: Merge (import) the REG file to delete the UniqueID entry
:Merge
REGEDIT /S %TEMP%.\UniqueID.reg
:: Delete the temporary REG file
DEL %TEMP%.\UniqueID.reg

ECHO Creating new LANDesk agent ID

:: Start inventory scan to create new ID
LDISCN32.EXE /NTT=%LANDeskServer%:5007 /S="%LANDeskServer%" /I=\\%LANDeskServer%\LDLOGON\ldappl.ini /V

ECHO Done
IF EXIST %TEMP%.\_Unique_.REG DEL %TEMP%.\_Unique_.REG
SET LANDeskServer=
CD\
GOTO End

:Syntax
ECHO UniqueID.bat,  Version 2.00 for 32-bit Windows
ECHO Create a new unique ID for Intel LANDesk agent
ECHO.
ECHO If a computer is installed using a harddisk image (like Norton Ghost
ECHO or PowerQuest's Drive Image) all "clones" will have the same LANDesk
ECHO agent ID if LANDesk agent was installed when the image was created.
ECHO However, the LANDesk agent needs a unique ID to function properly.
ECHO You can force a new ID by reinstalling the LANDesk agent software,
ECHO but running this batch file can force a new unique ID just as well.
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com

:End

NT 4

The following example, COUNTRY3.BAT for Windows NT 4, clearly demonstrates how to read registry settings using REGEDIT:

@ECHO OFF
:: Country.bat, Version 3.00 for Windows NT 4
:: Displays several country related settings.
:: This version uses native NT 4 commands only.
:: Written by Rob van der Woude
:: http://www.robvanderwoude.com
:: Keyboard trick by Tom Lavedas
:: http://www.pressroom.com/~tglbatch/

:: Export International settings from registry to a temporary file
START /W REGEDIT /E %Temp%.\international.reg "HKEY_CURRENT_USER\Control Panel\International"
:: Read several lines from the temporary files
:: and store these settings as environment variables
FOR /F "tokens=1* delims==" %%A IN ('TYPE %Temp%.\international.reg ^¦ FIND "iCountry"') DO SET iCountry=%%B
SET iCountry=%iCountry:"=%
SET iCountry
FOR /F "tokens=1* delims==" %%A IN ('TYPE %Temp%.\international.reg ^¦ FIND "sCountry"') DO SET sCountry=%%B
SET sCountry=%sCountry:"=%
SET sCountry
FOR /F "tokens=1* delims==" %%A IN ('TYPE %Temp%.\international.reg ^¦ FIND "sLanguage"') DO SET sLanguage=%%B
SET sLanguage=%sLanguage:"=%
SET sLanguage
:: Remove temporary file
DEL %Temp%.\international.reg
:: The KEYB trick was posted to the alt.msdos.batch.nt newsgroup by Tom Lavedas
FOR /F "tokens=1* delims=:" %%A IN ('KEYB ^¦ FIND ":" ^¦ FIND /V "CON"') DO SET Keyboard=%%B
SET Keyboard=%Keyboard:~1%
SET Keyboard
:: Check code page used
FOR /F "tokens=1* delims=:" %%A IN ('CHCP') DO SET /A CodePage = %%B
SET CodePage

The following example, GETRES.BAT (Version 3.00) for Windows NT 4/2000, also demonstrates how to read and parse registry settings using REGEDIT:

@ECHO OFF
:: No command line parameters please
IF NOT [%1]==[] GOTO Syntax

:: Verify OS version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Set initial values
SET VideoCard=
SET XResolution=
SET YResolution=
SET BitsPerPel=
SET VRefresh=

:: Read relevant registry entries and store them in a temporary REG file
REGEDIT /E "%Temp%.\Screen.reg" "HKEY_CURRENT_CONFIG\System\CurrentControlSet\Services"

:: Process the temporary REG file
FOR /F "tokens=* delims=" %%A IN ('TYPE %Temp%.\Screen.reg ^¦ FIND /V "REGEDIT4" ^¦ FIND /V ""') DO CALL :Parse01 %%A

:: Display results
ECHO.
SET VideoCard
SET XResolution
SET YResolution
SET BitsPerPel
SET VRefresh

:: Remove temporary file
IF EXIST "%Temp%.\Screen.reg" DEL "%Temp%.\Screen.reg"

:: Done
ENDLOCAL
GOTO:EOF


:Parse01
:: If this is the second card's entry, and the
:: first one was NOT VGA save mode, then quit
IF NOT "%VideoCard%"=="" IF NOT "%VideoCard%"=="%NewCard%" IF /I NOT "%VideoCard%"=="VgaSave" GOTO:EOF
:: Read subroutine's command line parameters as one line
SET Line=%*
:: Remove quotes from the line
SET Line=%Line:"=%
:: Remove spaces from the line
SET Line=%Line: =%
:: Check for and parse video card short name
IF "%Line:~0,6%"=="[HKEY_" FOR /F "tokens=5 delims=\]" %%A IN ('ECHO.%Line%') DO IF NOT "%%A"=="" SET NewCard=%%A
:: If this is the second card's entry, and the
:: first one was NOT VGA save mode, then quit
IF NOT "%VideoCard%"=="" IF NOT "%VideoCard%"=="%NewCard%" IF /I NOT "%VideoCard%"=="VgaSave" GOTO:EOF
:: If not, then save the new video adapter short name
SET VideoCard=%NewCard%
:: Parse all "key=value" lines
FOR /F "tokens=1* delims==" %%A IN ('ECHO.%Line%') DO CALL :Parse02 %%A %%B
:: End of subroutine Parse01
GOTO:EOF


:Parse02
:: Quit if either key or value aren't specified
IF "%2"=="" GOTO:EOF
:: %1 is key
SET InKey=%1
:: %2 is value
SET InValue=%2
:: Remove "Defaultvalue." prefix from key
FOR /F "tokens=2 delims=." %%a IN ('ECHO.%InKey%') DO SET Key=%%a
:: Continue only for these 4 keys, quit otherwise
IF /I NOT "%Key%"=="BitsPerPel" IF /I NOT "%Key%"=="XResolution" IF /I NOT "%Key%"=="YResolution" IF /I NOT "%Key%"=="VRefresh" GOTO:EOF
:: Parse value to check if it is a dword value
FOR /F "tokens=1,2 delims=:" %%a IN ('ECHO.%InValue%') DO (
	SET dWord=%%a
	SET xValue=%%b
)
:: If so, convert hexadecimal value to decimal
IF /I "%dWord%"=="dword" (SET /A Value = 0X%xValue%) ELSE (SET Value=%dWord%)
:: Store the result
SET %Key%=%Value%
:: End of subroutine Parse02
GOTO:EOF


:Syntax
ECHO.
ECHO GetRes.bat,  Version 3.00 for Windows NT 4 / 2000
ECHO Read and display video resolution settings from the registry
ECHO.
ECHO Usage:  GETRES
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO.